Rev 1 | Blame | Compare with Previous | Last modification | View Log | RSS feed
* Copyright (C) Maxim Integrated Products, Inc., All Rights Reserved.
*
* Permission is hereby granted, free of charge, to any person obtaining a
* copy of this software and associated documentation files (the "Software"),
* to deal in the Software without restriction, including without limitation
* the rights to use, copy, modify, merge, publish, distribute, sublicense,
* and/or sell copies of the Software, and to permit persons to whom the
* Software is furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included
* in all copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
* OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
* MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
* IN NO EVENT SHALL MAXIM INTEGRATED BE LIABLE FOR ANY CLAIM, DAMAGES
* OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
* ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
* OTHER DEALINGS IN THE SOFTWARE.
*
* Except as contained in this notice, the name of Maxim Integrated
* Products, Inc. shall not be used except as stated in the Maxim Integrated
* Products, Inc. Branding Policy.
*
* The mere transfer of this software does not imply any licenses
* of trade secrets, proprietary technology, copyrights, patents,
* trademarks, maskwork rights, or any other form of intellectual
* property whatsoever. Maxim Integrated Products, Inc. retains all
* ownership rights.
*******************************************************************************
* The MAX40658 is transimpedance amplifiers for optical distance measurement receivers
* for LiDAR applications.
**************************************************************************************
.SUBCKT MAX40658 VCC IN CCAP OFFSET NC OUT+ OUT- GND
* | | | | | | | |
* | | | | | | | Circuit Ground
* | | | | | | |
* | | | | | | Negative 75Ω Output
* | | | | | |
* | | | | | Positive 75Ω Output
* | | | | |
* | | | | No Connection/Ground
* | | | |
* | | | Offset adjustment current input
* | | |
* | | Capacitor connection for clamp bias
* | |
* | Signal Input
* |
* +3.3V Supply Voltage
****************************************************************************
* Initial date of model creation:
* Feb.21/2017
*
* Revision History:
* Version 1: Initial，2017
* Version 2: Update OFFSET bias voltage,2022
*
* Recommendations:
* Use SIMETRIX (or SPICE 2G6; other simulators may require translation)
* For a quick, effective design, use a combination of: data sheet
* specs, bench testing, and simulations with this macromodel
* For PSpice .options ITL4=20 can be used for convergence
*
* Supported:
* Small Signal Transimpedance, Output Differential Voltage Vs Input DC Current for IOffset Variation, Output Differential Voltage Vs Offset Adjustment Current Input
* Supply Current Vs Input DC Current, Supply Current Vs Supply Voltage, Input Bias Voltage
* Model works only at temperature 27 degree celsius
*
* Not Supported:
* This model does not operate other than 27 degree celsius
*
* Known Discrepancies in Model vs. Datasheet:
* Bandwidth and Pulse Response mismatches from Datasheet.
*
*=======================
Vin0 IN 1 0
Din 1 ccap D1
.model D1 D
Rin ccap 3 27
Vbias 3 0 0.355
Rin1 IN 200 400
Vin1 200 0 0.78
Esu su 0 value={I(Vin0)+I(Vin1)}
E1 4 0 value={(V(su)-V(vf)-1.5u)*36.6k}
R1 4 5 100
C1 5 0 2.75p
C6 out+ 0 1p
C7 out- 0 1p
E6 6 0 table {V(5)} =(-100,-240m) (-420.9m,-240m) (-384.3m,-238.5m) (-347.7m,-235.5m) (-311.1m,-232m) (-274.5m,-224m) (-237.9m,-208m) (-201.3m,-178m) (-164.7m,-156m) (-128.1m,-128m) (-91.5m,-92m) (-54.9m,-54.9m) (-18.3m,-24m) (18.3m,16m) (54.9m,52m) (91.5m,92m) (128.1m,128m) (164.7m,156m) (201.3m,178m) (237.9m,204m) (274.5m,216m) (311.1m,228m) (347.7m,234m) (384.3m,237m) (420.9m,240m) (100,240m)
Evocm vocm 0 value={V(VCC)-0.12}
Eo1 out1+ vocm value={V(6)*0.5}
Eo2 vocm out1- value={V(6)*0.5}
Eh high 0 value={V(VCC)-0.78403}
El low 0 value={V(VCC)+0.53403}
Gs VCC 0 value={21m}
Roff offset 50 240
V50 50 0 0.78
V00 out1+ out2+ 0
Eof vf 0 value={(V(offset)-0.78)*0.25/240}
Ro1 out2+ out+ 75
Ro2 out1- out- 75
Ro- out1- 0 10meg
Roo out+ out- 10t
.ends MAX40658