Rev 10 | Blame | Compare with Previous | Last modification | View Log | RSS feed
*LMH6654
*****************************************************************************
* (C) Copyright 2016 Texas Instruments Incorporated. All rights reserved.
*****************************************************************************
** This model is designed as an aid for customers of Texas Instruments.
** TI and its licensors and suppliers make no warranties, either expressed
** or implied, with respect to this model, including the warranties of
** merchantability or fitness for a particular purpose. The model is
** provided solely on an "as is" basis. The entire risk as to its quality
** and performance is with the customer.
*****************************************************************************
*
** Released by: WEBENCH(R) Design Center, Texas Instruments Inc.
* Part: LMH6654
* Date: 04/05/2016
* Model Type: All In One
* Simulator: PSPICE
* Simulator Version: 16.2.0.p001
* EVM Order Number: N/A
* EVM Users Guide: N/A
* Datasheet: SNOS956E
*
* Model Version: 1.0
*
*****************************************************************************
*
* Updates:
*
* Version 1.0 : Release to Web
*
*****************************************************************************
* NOTES:
* 1. MODEL FEATURES INCLUDE OUTPUT SWING, OUTPUT CURRENT THRU
* THE SUPPLY RAILS, GAIN AND PHASE, SLEW RATE, COMMON MODE
* REJECTION WITH FREQUENCY EFFECTS, POWER SUPPLY REJECTION
* ON BOTH RAILS WITH FREQUENCY EFFECTS, INPUT VOLTAGE NOISE
* WITH 1/F,INPUT CURRENT NOISE WITH 1/F, AND QUIESCENT
* CURRENT CHANGE WITH SUPPLY VOLTAGE. MODEL PERFORMANCE
* CHANGES ONLY SLIGHTLY WITH SUPPLY AS PER DATA SHEET.
* 2. MODEL TEMP RANGE IS -55 TO +125 DEG C.
* 3. MODEL IS FUNCTIONAL OVER THIS RANGE BUT NOT ALL
* PARAMETERS TRACK THOSE OF THE REAL PART.
*
*******************************************************************************
* LMH6654 SUBCIRCUIT
* NOTE - THIS MODEL HAS PINOUT
* FOR THE A AMPLIFIER ONLY
* PINOUT ORDER -IN +IN VCC VEE OUT
* PINOUT 2 3 8 4 1
.SUBCKT LMH6654 2 3 8 4 1
I2 8 32 1.25E-3
I5 39 4 1.25E-3
R1 9 0 1.8E6
D1 9 34 D1M
D2 18 0 DV2M
E1 34 0 5 0 1.0
R2 9 5 100
C1 5 12 2.2E-12
D7 23 0 DV2M
G2 0 13 5 0 0.1
I4 0 18 1.068E-4
R3 13 0 10
C2 13 0 75E-12
G4 0 14 13 0 0.1
R4 14 0 10
C3 14 0 5.2E-12
D10 19 8 D10M
V1 19 20 2.1
I8 0 23 1.068E-4
D15 4 21 D10M
V2 22 21 1.73
I7 28 29 3.2E-6
E3 3 45 23 18 0.55
D8 37 0 DI8M
C4 26 0 6.5E-12
D11 34 9 D1M
E2 5 22 27 0 1
E4 20 5 27 0 1
I3 0 30 1E-3
D12 30 0 D12M
D9 40 0 DI8M
I9 0 37 1.068E-4
V3 27 30 -0.71465
R6 8 4 50E3
V4 12 0 0
L1 31 1 2.5E-9
I1 8 4 0.5E-3
Q34 33 28 29 Q34M
Q35 17 35 36 Q35M
Q36 16 2 38 Q35M
Q1 8 32 26 Q1M
R11 33 36 325
R12 33 38 325
Q2 8 14 39 Q2M
Q3 4 39 26 Q3M
Q4 4 14 32 Q4M
I10 0 40 1.068E-4
R7 31 1 1E3
R9 26 31 9.7
V6 35 45 1E-3
G3 2 45 40 37 0.49E-6
R10 16 4 2E3
R13 17 4 2E3
G5 0 9 16 17 0.815E-3
G6 0 9 0 81 -1E-8
G7 0 9 0 48 -8.8E-7
D3 35 8 D3M
I6 35 4 2.95E-6
I11 2 4 2.65E-6
D4 2 8 D3M
D5 4 35 D3M
D6 4 2 D3M
V7 8 29 0.63
G1 0 48 8 0 1
R17 49 48 1
L2 0 49 1.2E-6
R20 0 49 1200
G9 0 57 4 0 1
R21 74 57 1
L5 0 74 1.2E-6
R22 0 74 1200
G10 0 9 57 0 8.8E-8
R34 81 82 1
L6 82 0 2E-5
R35 82 0 3E3
R23 3 0 1E12
R24 27 0 1E12
G12 0 81 33 0 1
C8 45 0 1.8E-12
C9 2 0 1.8E-12
D18 1 8 D3M
D19 4 1 D3M
.MODEL D1M D IS=5.002E-16
.MODEL DV2M D IS=1E-16 KF=2E-14
.MODEL D10M D IS=1E-15
.MODEL DI8M D IS=1E-16 KF=1E-15
.MODEL D12M D IS=7E-9 M=0.333 N=1.67
+ RS=2.95E-01 TT=2.88E-09 VJ=0.75
.MODEL Q34M PNP
.MODEL Q35M PNP BF=40 KF=1.1E-14
.MODEL Q1M NPN BF=224 RC=1 RE=0.3
.MODEL Q2M NPN BF=75
.MODEL Q3M PNP BF=149 RC=3 RE=1
.MODEL Q4M PNP BF=75
.MODEL D14M D IS=1.0E-14 RS=2700
.MODEL D3M D IS=3E-14 RS=0.5
.ENDS