Subversion Repositories Electronics.Rangefider

*Oct 3, 2005
*Doc. ID: 77873, S-52018, Rev. A
*File Name: Si5517DU_PS.txt and Si5517DU_PS.lib
                           *Dn Gn Sn Dp Gp Sp
.SUBCKT Si5517DU 6 2 1 3 5 4
X1 6 2 1 Si5517N
X2 3 5 4 Si5517P
.ENDS Si5517DU
*N-CH
.SUBCKT Si5517N 4 1 2
M1  3 1 2 2 NMOS W=485249u L=0.25u
M2  2 1 2 4 PMOS W=485249u L=0.23u
R1  4 3     RTEMP 16E-3
CGS 1 2     400E-12
DBD 2 4     DBD
****************************************************************
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 1.7E-8
+ RS     = 11E-3          RD     = 0            NSUB   = 2.3E17
+ KP     = 2.6E-5         UO     = 650
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 5E-2
+ ETA    = 1E-4           TPG    = 1
+ IS     = 0              LD     = 0
+ CGSO   = 0              CGDO   = 0            CGBO   = 0
+ NFS    = 0.8E12         DELTA  = 0.1)
****************************************************************
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 1.7E-8
+NSUB    = 4E17           TPG    = -1)
****************************************************************
.MODEL DBD D (CJO=70E-12 VJ=0.38 M=0.22
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=20.2)
****************************************************************
.MODEL RTEMP RES (TC1=5E-3 TC2=5.5E-6)
****************************************************************
.ENDS Si5517N
*P-CH
.SUBCKT Si5517P 4 1 2
M1  3 1 2 2 PMOS W=399031u L=0.50u
M2  2 1 2 4 NMOS W=399031u L=0.50u
R1  4 3     RTEMP 30E-3
CGS 1 2     120E-12
DBD 4 2     DBD
****************************************************************
.MODEL  PMOS         PMOS (LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 20E-3           RD     = 0           NSUB   = 5E15
+ KP     = 2.7E-5          UO     = 400
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 3E-3
+ ETA    = 1E-4            TPG    = -1
+ IS     = 0               LD     = 0
+ CGSO   = 0               CGDO   = 0           CGBO   = 0
+ NFS    = 0.8E12          DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS         NMOS (LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 1E17            TPG    = -1)
*****************************************************************
.MODEL DBD D (CJO=80E-12 VJ=0.38 M=0.17
+RS=0.1 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=20.5)
*****************************************************************
.MODEL RTEMP RES (TC1=5E-3 TC2=5.5E-6)
*****************************************************************
.ENDS Si5517P