Subversion Repositories Electronics.Rangefider

*****************************************************************

*                                            					*

* GaN Systems Inc. Power Transistors                            *

* PSpice Library for GaN Transistors                            *

* Version 4.1                                                   *

*                                                               *

*****************************************************************

*****************************************************************

*                                                               *

* Models provided by GaN Systems Inc. are not warranted by      *

* GaN Systems Inc. as                                           *

* fully representing all of the specifications and operating    *

* characteristics of the semiconductor product to which the     *

* model relates. The model describe the characteristics of a    *

* typical device.                                               *

* In all cases, the current data sheet information for a given  *

* device is the final design guideline and the only actual      *

* performance specification.                                    *

* Altough models can be a useful tool in evaluating device      *

* performance, they cannot model exact device performance under *

* all conditions, nor are they intended to replace bread-       *

* boarding for final verification. GaN Systems Inc. therefore   *

* does not assume any liability arising from their use.         *

* GaN Systems Inc. reserves the right to change models without  *

* prior notice.                                                 *

*                                                               *

* This library contains models of the following GaN Systems     *

* Inc. transistors:                                             *

*                                                               *

*   GS61008P                                                    *

*****************************************************************

*Level 3. In addition to Level 2, this level includes the stray inductance in the package.

*$

*$

.subckt GaN_PSpice_GS61008P_L3V4P1 gatein drainin sourcein source_S TC TJ

*

*

.param rTC=-0.004  gan_res={3.38e-03}		metal_res={2.0e-3}   gtc=3.275 sh_s=0.239   sh_d=0.761

.param  cur=0.089   x0_0=1.1	  x0_1=1.1  x0_2=1.0  thr=1.8  itc=0.83 atc=180.15

*

*

.param tscl = 0.5

Cth_1 0 TJ {(7.0e-4)*tscl}

Cth_2 0 T11  {(6.7e-3)*tscl}

Cth_3 0 T22 {(5.9e-3)*tscl}

Cth_4 0 T33 {(1.8e-3)*tscl}

*

*

Rth_1 T11 TJ {0.017}

Rth_2 T22 T11 {0.253}

Rth_3 T33 T22 {0.264}

Rth_4 TC T33 {0.017}

*

*

gdtemp 0 TJ value { (if(v(drain,source)>0,

+   (cur*(-(v(TJ)-25)*itc+atc)*log(1.0+exp(26*(v(gate,source)-thr)))*

+	v(drain,source)/(1 + max(x0_0+x0_1*(v(gate,source)+x0_2),0.2)*v(drain,source)))*

+	v(drain,source),

+   (cur*(-(v(TJ)-25)*itc+atc)*log(1.0+exp(26*(v(gate,drain)-thr)))*

+	v(source, drain)/(1 + max(x0_0+x0_1*(v(gate,drain)+x0_2),0.2)*v(source,drain)))*

+	v(drain,source))) }

*

*

ld drainin drain3 {370e-12}

ERES_d drain3 3_d value={I(VSENSE_d)*sh_d* (metal_res*(1-1*rTc*(V(TJ)-25)) + gan_res*PWR((v(TJ)+273)/298,gtc)) }

VSENSE_d 3_d drain DC 0

*

*

VSENSE_s 3_s source DC 0

ERES_s source3 3_s value={I(VSENSE_s)* sh_s * (metal_res*(1-1*rTc*(V(TJ)-25)) + gan_res*PWR((v(TJ)+273)/298,gtc)) }

Lcs source3 source3b {20e-12}

Ls sourcein source3b {150e-12}

*

*

RSS source_S1 source3b {0.001}

LSS source_S source_S1 {0.2e-9}

rg gatein gate1 {1.5}

Lg gate1 gate {3.1e-9}

*

*

Rcsdconv drain source {4000Meg}

Rcgsconv gate source {4000Meg}

Rcgdconv gate drain {4000Meg}

*

*

gswitch drain2 source2 value { (if(v(drain2,source2)>0,

+   (cur*(-(v(TJ)-25)*itc+atc)*log(1.0+exp(26*(v(gate,source2)-thr)))*

+	v(drain2,source2)/(1 + max(x0_0+x0_1*(v(gate,source2)+x0_2),0.2)*v(drain2,source2))),

+   (-cur*(-(v(TJ)-25)*itc+atc)*log(1.0+exp(26*(v(gate,drain2)-thr)))*

+	v(source2, drain2)/(1 + max(x0_0+x0_1*(v(gate,drain2)+x0_2),0.2)*v(source2,drain2))))) }

*

*

R_drain2 drain2 drain {(1e-7)}

R_source2 source2 source {(1e-7)}

*

*

C_GS1  gate source  	{6.04e-10}

E_IS1 tl_gs1 bl_gs1	Value = { ( - 14.08e-11*(1-1./(1+exp(0.32*(-v(drain, source)+8.0))))

+                       - 1.653e-11*(1-1./(1+exp(0.029*(-v(drain, source)+80.0))))

+    				    - 1.5e-10*(-1+1./(1+exp(0.16*(-v(drain, source)-2.1)))) )*v(gate,source) }

V_INGS1 br_gs1 bl_gs1 	{0.0}

C_IGS1  br_gs1 tr_gs1 	{1.0e-6}

R_IGS1  tr_gs1 tl_gs1 	{1e-3}

F_IGS1  gate source 	V_INGS1 {1.0e6}

R_IGS12 bl_gs1 source 	{100Meg}

*

*

E_IGS2	tl_gs2 bl_gs2 	Value = { ( 1.0e-010*log(1+exp(6.1*(v(gate,source)-2.2)))) }

V_INGS2 br_gs2 bl_gs2 	{0.0}

C_IGS2  br_gs2 tr_gs2 	{1.0e-6}

R_IGS2  tr_gs2 tl_gs2 	{1e-3}

F_IGS2  gate source 	V_INGS2 {1.0e6}

R_IGS22 bl_gs2 source 	{100Meg}

*

*

C_GD  gate drain	{0.6e-012}

E_IGD	tl_gd bl_gd		Value = { (44e-11*log(1+exp(0.32*(v(gate, drain)+8)))

+					 	  + 57e-11*log(1+exp(0.029*(v(gate, drain)+80))) ) }

V_INGD br_gd bl_gd 	{0.0}

C_IGD  br_gd tr_gd 	{1.0e-6}

R_IGD  tr_gd tl_gd 	{1e-3}

F_IGD  gate drain 	V_INGD {1.0e6}

R_IGD2 bl_gd drain 	{100Meg}

*

*

C_SD  source drain  {2.18e-010}

E_ISD	tl_sd bl_sd		Value = { (44e-11*log(1+exp(0.32*(v(source2,drain2)+8)))

+						 + 57e-11*log(1+exp(0.029*(v(source2,drain2)+80)))

+						 + 1.95e-10*log(1+exp(1.19*(v(source2,drain2)+16)))

+						 + 1.69e-9*log(1+exp(0.07*(v(source2,drain2)+31))) ) }

V_INSD br_sd bl_sd 	{0.0}

C_ISD  br_sd tr_sd 	{1.0e-6}

R_ISD  tr_sd tl_sd 	{1e-3}

F_ISD  source2 drain2	V_INSD {1.0e6}

R_ISD2 bl_sd drain2 {100Meg}

*

*

.ends

*$